CSDN博客

img 40Star

使用Windows消息控制Winamp(VB)

发表于2002/6/24 9:25:00  1091人阅读

第一部分:得到Winamp的窗口

Winamp是一个32位的Windows应用程序。也就是说,我们可以使用32位的Windows编程的一些基础技术来实现控制Winamp,即使用Windows的消息系统。在你给Winamp发送消息之前,你必须得到Winamp窗口的句柄。这里有个方法,使用外部应用程序(例如你自己编写的VB应用)就可以达到要求。

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Dim hwndWinamp as long
hwndWinamp = FindWindow("Winamp v1.x",vbNullString)

大家可能会注意到一点,为什么要使用类名"Winamp v1.x"来FindWindow呢?因为Winamp 1.x 和 2.x 的所有版本都是用"Winamp v1.x"这个class name的。


第二部分:使用消息

Winamp相应的三个消息:WM_USER,WM_COMMAND,和 WM_COPYDATA。WM_USER 和 WM_COPYDATA 允许你可以对Winamp进行一些高级的控制。而WM_COMMAND则可以做一些简单的操作,如暂停,播放,和跳到下一首音乐。

1.WM_COMMAND 消息:

  Previous track button                   40044
  Next track button                       40048
  Play button                             40045
  Pause/Unpause button                    40046
  Stop button                             40047
  Fadeout and stop                        40147
  Stop after current track                40157
  Fast-forward 5 seconds                  40148
  Fast-rewind 5 seconds                   40144
  Start of playlist                       40154
  Go to end of playlist                   40158
  Open file dialog                        40029
  Open URL dialog                         40155
  Open file info box                      40188
  Set time display mode to elapsed        40037
  Set time display mode to remaining      40038
  Toggle preferences screen               40012
  Open visualization options              40190
  Open visualization plug-in options      40191
  Execute current visualization plug-in   40192
  Toggle about box                        40041
  Toggle title Autoscrolling              40189
  Toggle always on top                    40019
  Toggle Windowshade                      40064
  Toggle Playlist Windowshade             40266
  Toggle doublesize mode                  40165
  Toggle EQ                               40036
  Toggle playlist editor                  40040
  Toggle main window visible              40258
  Toggle minibrowser                      40298
  Toggle easymove                         40186
  Raise volume by 1%                      40058
  Lower volume by 1%                      40059
  Toggle repeat                           40022
  Toggle shuffle                          40023
  Open jump to time dialog                40193
  Open jump to file dialog                40194
  Open skin selector                      40219
  Configure current visualization plug-in 40221
  Reload the current skin                 40291
  Close Winamp                            40001
  Moves back 10 tracks in playlist        40197
  Show the edit bookmarks                 40320
  Adds current track as a bookmark        40321
  Play audio CD                           40323
  Load a preset from EQ                   40253
  Save a preset to EQF                    40254
  Opens load presets dialog               40172
  Opens auto-load presets dialog          40173
  Load default preset                     40174
  Opens save preset dialog                40175
  Opens auto-load save preset             40176
  Opens delete preset dialog              40178
  Opens delete an auto load preset dialog 40180

例程:控制Winamp暂停,播放,和跳到下一首音乐
新建一个标准EXE工程,加入一个模块,在模块中加入代码----------

Option Explicit

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Const WM_COMMAND = &H111
Const IPC_WINAMP_NextTrackButton = 40048    '跳到下一首音乐
Const IPC_WINAMP_PlayButton = 40045         '播放
Const IPC_WINAMP_PauseUnpauseButton = 40046 '暂停
Public hwndWinamp As Long                   'Winamp的句柄

Public Sub WinampPlay() '播放
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_PlayButton, 0
End Sub

Public Sub WinampPause() '暂停
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_PauseUnpauseButton, 0
End Sub

Public Sub WinampNext() '跳到下一首音乐
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_NextTrackButton, 0
End Sub

在Form中加入的代码----------

Option Explicit

Private Sub cmdNext_Click()
WinampNext '跳到下一首音乐
End Sub

Private Sub cmdPause_Click()
WinampPause '暂停
End Sub

Private Sub cmdPlay_Click()
WinampPlay '播放
End Sub

Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判断Winamp是否运行
   MsgBox "请启动Winamp先!"
   Unload Me
End If
End Sub


2.WM_USER 消息:

例程:得到Winamp的版本
新建一个标准EXE工程,加入一个模块,在模块中加入代码----------

Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'这是VB的API声明,不会返回正确的结果
'Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

'这是正确的SendMessage声明,才能返回版本信息,读者可以参考一下两者的不同
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Const WM_USER = &H400
Const WA_GETVERSION = 0
Public hwndWinamp As Long                   'Winamp的句柄

Function WinampGetVersion() As String
Dim VersionNum As Long
Dim ReturnVersion As String
VersionNum = SendMessage(hwndWinamp, WM_USER, 0, WA_GETVERSION)

If Len(Hex(VersionNum)) > 3 Then
   ReturnVersion = Left(Hex(VersionNum), 1) & "."
   ReturnVersion = ReturnVersion & Mid(Hex(VersionNum), 2, 1)
   ReturnVersion = ReturnVersion & Right$(Hex(VersionNum), Len(Hex(VersionNum)) - 3)
   WinampGetVersion = ReturnVersion
Else
   WinampGetVersion = "UNKNOWN"
End If
End Function

在Form中加入的代码----------

Option Explicit

Private Sub Command1_Click()
MsgBox "你的Winamp的版本是:" & WinampGetVersion
End Sub

Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判断Winamp是否运行
   MsgBox "请启动Winamp先!"
   Unload Me
End If
End Sub


3.WM_COPYDATA 消息:

例程:Winamp的运行时刻在播放列表中加入一首Mp3的歌曲
新建一个标准EXE工程,加入一个模块,在模块中加入代码----------

Option Explicit

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function lstrcpy Lib "kernel32" Alias "lstrcpyA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function CopyDataSendMessage Lib "user32" Alias "SendMessageA" (ByVal WndID As Long, ByVal wMsg As Long, ByVal wParam As Long, ByRef lParam As COPYDATASTRUCT) As Long
Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type

Const IPC_PLAYFILE = 100
Const WM_COPYDATA = &H4A

Public hwndWinamp As Long

Public Sub WinampAddSong(SongName As String)
Dim CDS As COPYDATASTRUCT
With CDS
      .dwData = IPC_PLAYFILE
      .cbData = 100
      .lpData = lstrcpy(SongName, SongName)
End With
CopyDataSendMessage hwndWinamp, WM_COPYDATA, 0&, CDS
End Sub

在Form中加入的代码----------

Option Explicit

Private Sub Command1_Click()
WinampAddSong "I:/Mp3/周杰伦-简单爱.mp3" '加入一首歌
End Sub

Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判断Winamp是否运行
   MsgBox "请启动Winamp先!"
   Unload Me
End If
End Sub

所有例程在 Win2000 + VB6 中调试通过

0 0

相关博文

我的热门文章

img
取 消
img