编程语言

img kicklee

Windows的动态链接库原理

发表于2004/11/4 12:55:00  789人阅读

    动态链接库(DLLs)是从C语言函数库和Pascal库单元的概念发展而来的。所有的C语言标准库函数都存放在某一函数库中,同时用户也可以用LIB程序创建自己的函数库。在链接应用程序的过程中,链接器从库文件中拷贝程序调用的函数代码,并把这些函数代码添加到可执行文件中。这 
种方法同只把函数储存在已编译的.OBJ文件中相比更有利于代码的重用。 
  但随着Windows这样的多任务环境的出现,函数库的方法显得过于累赘。如果为了完成屏幕输出、消息处理、内存管理、对话框等操作,每个程序都不得不拥有自己的函数,那么Windows程序将变得非常庞大。Windows的发展要求允许同时运行的几个程序共享一组函数的单一拷贝。动态 
链接库就是在这种情况下出现的。动态链接库不用重复编译或链接,一旦装入内存,Dlls函数可以被系统中的任何正在运行的应用程序软件所使用,而不必再将DLLs函数的另一拷贝装入内存。 

10.1.1 动态链接库的工作原理 

  "动态链接"这几字指明了DLLs是如何工作的。对于常规的函数库,链接器从中拷贝它需要的所有库函数,并把确切的函数地址传送给调用这些函数的程序。而对于DLLs,函数储存在一个独立的动态链接库文件中。在创建Windows程序时,链接过程并不把DLLs文件链接到程序上。直到程 
序运行并调用一个DLLs中的函数时,该程序才要求这个函数的地址。此时Windows才在DLLs中寻找被调用函数,并把它的地址传送给调用程序。采用这种方法,DLLs达到了复用代码的极限。 
  动态链接库的另一个方便之处是对动态链接库中函数的修改可以自动传播到所有调用它的程序中,而不必对程序作任何改动或处理。 
  DLLs不仅提供了函数重用的机制,而且提供了数据共享的机制。任何应用程序都可以共享由装入内存的DLLs管理的内存资源块。只包含共享数据的DLLs称为资源文件。如Windows的字体文件等。 

10.1.2 Windows系统的动态链接库 

  Windows本身就是由大量的动态链接库支持的。这包括Windows API函数 ( KRNLx86.EXE,USER.EXE,GDI.EXE,…),各种驱动程序文件,各种带有.Fon和.Fot 
扩展名的字体资源文件等。Windows还提供了针对某一功能的专用DLLs,如进行DDE编程的ddeml.dll,进行程序安装的ver.dll等。 
  虽然在编写Windows程序时必然要涉及到DLLs,但利用Delphi ,用户在大部分时候并不会注意到这一点。这一方面是因为Delphi提供了丰富的函数使用户不必直接去使用Windows API;另一方面即使使用Windows API,由于Delphi把API函数和其它Windows 
DLLs函数重新组织到了几个库单元中,因而也不必使用特殊的调用格式。所以本章的重点放在编写和调用用户自定义的DLLs上。 
  使用传统的Windows编程方法来创建和使用一个DLLs是一件很令人头痛的事,正如传统的Windows编程方法本身就令人生畏一样。用户需要对定义文件、工程文件进行一系列的修改以适应创建和使用DLLs的需要。Delphi的出现,在这一方面,正如在其它许多方面所做的那样,减轻了开发 
者的负担。更令人兴奋的是Delphi利用DLLs 实现了窗体的重用机制。用户可以将自己设计好的窗体储存在一个DLLs中,在需要的时候可随时调用它。 

10.2 DLLs的编写和调用 

10.2.1 DLLs的编写 

  在Delphi环境中,编写一个DLLs同编写一个一般的应用程序并没有太大的区别。事实上作为DLLs 主体的DLL函数的编写,除了在内存、资源的管理上有所不同外,并不需要其它特别的手段。真正的区别在工程文件上。 
  在绝大多数情况下,用户几乎意识不到工程文件的存在,因为它一般不显示在屏幕上。如果想查看工程文件,则可以打开View菜单选择Project Source项,此时工程文件的代码就会出现在屏幕的Code Editor(代码编辑器)中。 
  一般工程文件的格式为: 

  program   工程标题; 
  uses     子句; 
  程序体 

  而DLLs工程文件的格式为: 

  library 工程标题; 
  uses 子句; 
  exprots 子句; 
  程序体 

  它们主要的区别有两点: 
  1.一般工程文件的头标用program关键字,而DLLs工程文件头标用library 关键字。不同的关键字通知编译器生成不同的可执行文件。用program关键字生成的是.exe文件,而用library关键字生成的是.dll文件; 
  2.假如DLLs要输出供其它应用程序使用的函数或过程,则必须将这些函数或过程列在exports子句中。而这些函数或过程本身必须用export编译指令进行编译。 
  根据DLLs完成的功能,我们把DLLs分为如下的三类: 
1.完成一般功能的DLLs; 
2.用于数据交换的DLLs; 
3.用于窗体重用的DLLs。 
  这一节我们只讨论完成一般功能的DLLs,其它内容将在后边的两节中讨论。 

10.2.1.1 编写一般DLLs的步骤 

  编写一般DLLs的步骤如下: 
  1.利用Delphi的应用程序模板,建立一个DLLs程序框架。 
  对于Delphi 1.0的用户,由于没有DLLs模板,因此: 
  (1).建立一个一般的应用程序,并打开工程文件; 
  (2).移去窗体和相应的代码单元; 
  (3).在工程文件中,把program改成library,移去Uses子句中的Forms,并添加适当的库单元(一般SysUtils、Classes是需要的),删去begin...end之间的所有代码。 
  2.以适当的文件名保持文件,此时library后跟的库名自动修改; 
  3.输入过程、函数代码。如果过程、函数准备供其它应用程序调用,则在过程、函数头后加上export 编译指示; 
  4.建立exports子句,包含供其它应用程序调用的函数和过程名。可以利用标准指示 name 、Index、resident以方便和加速过程/函数的调用; 
  5.输入库初始化代码。这一步是可选的; 
  6.编译程序,生成动态链接库文件。 

10.2.1.2 动态链接库中的标准指示 

  在动态链接库的输出部分,用到了三个标准指示:name、Index、resident。 
  1.name 
  name后面接一个字符串常量,作为该过程或函数的输出名。如: 

exports 
InStr name MyInstr; 

  其它应用程序将用新名字(MyInstr)调用该过程或函数。如果仍利用原来的名字(InStr),则在程序执行到引用点时会引发一个系统错误。 
  2.Index 
  Index指示为过程或函数分配一个顺序号。如果不使用Index指示,则由编译器按顺序进行分配。 
  Index后所接数字的范围为1...32767。使用Index可以加速调用过程。 
  3.resident 
  使用resident,则当DLLs装入时特定的输出信息始终保持在内存中。这样当其它应用程序调用该过程时,可以比利用名字扫描DLL入口降低时间开销。 
  对于那些其它应用程序常常要调用的过程或函数,使用resident指示是合适的。例如: 

exports 
InStr name MyInStr resident; 

10.2.1.3 DLLs中的变量和段 

一个DLLs拥有自己的数据段(DS),因而它声明的任何变量都为自己所私有。调用它的模块不能直接使用它定义的变量。要使用必须通过过程或函数界面才能完成。而对DLLs来说,它永远都没有机会使用调用它的模块中声明的变量。 
  一个DLLs没有自己的堆栈段(SS),它使用调用它的应用程序的堆栈。因此在DLL中的过程、函数绝对不要假定DS = SS。一些语言在小模式编译下有这种假设,但使用Delphi可以避免这种情况。Delphi绝不会产生假定DS = 
SS的代码,Delphi的任何运行时间库过程/函数也都不作这种假定。需注意的是如果读者想嵌入汇编语言代码,绝不要使SS和DS登录同一个值。 

10.2.1.4 DLLs中的运行时间错和处理 

  由于DLLs无法控制应用程序的运行,导致很难进行异常处理,因此编写DLLs时要十分小心,以确保被调用时能正常执行 
。当DLLs中发生一个运行时间错时,相应DLLs并不一定从内存中移去(因为此时其它应用程序可能正在用它),而调用DLLs的程序异常中止。这样造成的问题是当DLLs已被修改,重新进行调用时,内存中保留的仍然可能是以前的版本,修改后的程序并没有得到验证。对于这个问题,有以下 
两种解决方法: 
  1.在程序的异常处理部分显式将DLL卸出内存; 
  2.完全退出Windows,而后重新启动,运行相应的程序。 
  同一般的应用程序相比,DLL中运行时间错的处理是很困难的,而造成的后果也更为严重。因此要求程序设计者在编写代码时要有充分、周到的考虑。 

10.2.1.5 库初始化代码的编写 

  传统Windows中动态链接库的编写,需要两个标准函数:LibMain和WEP,用于启动和关闭DLL。在LibMain中,可以执行开锁DLL数据段、分配内存、初始化变量等初始化工作;而WEP在从内存中移去DLLs前被调用,一般用于进行必要的清理工作,如释放内存等。Delphi用自己特有的方式 
实现了这两个标准函数的功能。这就是在工程文件中的begin...end部分添加初始化代码。和传统Windows编程方法相比,它的主要特色是: 
  1.初始化代码是可选的。一些必要的工作(如开锁数据段)可以由系统自动完成。所以大部分情况下用户不会涉及到; 
  2.可以设置多个退出过程,退出时按顺序依次被调用; 
  3.LibMain和WEP对用户透明,由系统自动调用。 
  初始化代码完成的主要工作是: 
  1.初始化变量、分配全局内存块、登录窗口对象等初始化工作。在(10.3.2)节"利用DLLs实现应用程序间的数据传输"中,用于数据共享的全局内存块就是在初始化代码中分配的。 
  2.设置DLLs退出时的执行过程。Delphi有一个预定义变量ExitProc用于指向退出过程的地址。用户可以把自己的过程名赋给ExitProc。系统自动调用WEP函数,把ExitProc指向的地址依次赋给WEP执行,直到ExitProc为nil。 
  下边的一段程序包含一个退出过程和一段初始化代码,用来说明如何正确设置退出过程。 

library Test; 
{$S-} 
uses WinTypes, WinProcs; 
var 
SaveExit: Pointer; 

procedure LibExit; far; 
begin 
if ExitCode = wep_System_Exit then 
begin 
{ 系统关闭时的相应处理 } 
end 
else 
begin 
{ DLL卸出时的相应处理 } 
end; 
ExitProc := SaveExit; { 恢复原来的退出过程指针 } 
end; 

begin 
{DLL的初始化工作 } 
SaveExit := ExitProc; { 保存原来的退出过程指针 } 
ExitProc := @LibExit; { 安装新的退出过程 } 
end. 

  在初始化代码中,首先把原来的退出过程指针保存到一个变量中,而后再把新的退出过程地址赋给ExitProc。而在自定义退出过程LibExit结束时再把ExitProc的值恢复。由于ExitProc是一个系统全局变量,所以在结束时恢复原来的退出过程是必要的。 
  退出过程LibExit中使用了一个系统定义变量ExitCode,用于标志退出时的状态。 ExitCode的取值与意义如下: 

表10.1 ExitCode的取值与意义 
━━━━━━━━━━━━━━━━━━━━━ 
取 值 意 义 
--------------------- 
  WEP_System_Exit Windows关闭 

WEP_Free_DLLx DLLs被卸出 
━━━━━━━━━━━━━━━━━━━━━ 

  退出过程编译时必须关闭stack_checking,因而需设置编译指示 {$S-} 。 

10.2.1.6 编写一般DLLs的应用举例 

  在下面的程序中我们把一个字符串操作的函数储存到一个DLLs中,以便需要的时候调用它。应该注意的一点是:为了保证这个函数可以被其它语言编写的程序所调用,作为参数传递的字符串应该是无结束符的字符数组类型(即PChar类型),而不是Object 
Pascal的带结束符的Srting类型。程序清单如下: 

library Example; 
uses 
SysUtils, 
Classes; 

{返回字符在字符串中的位置} 
function InStr(SourceStr: PChar;Ch: Char): Integer; export; 
var 
Len,i: Integer; 
begin 
Len := strlen(SourceStr); 
for i := 0 to Len-1 do 
if SourceStr[i] = ch then 
begin 
Result := i; 
Exit; 
end; 
Result := -1; 
end; 

exports 
Instr Index 1 name 'MyInStr' resident; 

begin 
end. 


10.2.2 调用DLLs 

  有两种方法可用于调用一个储存在DLLs中的过程。 
  1.静态调用或显示装载 
  使用一个外部声明子句,使DLLs在应用程序开始执行前即被装入。例如: 

  function Instr(SourceStr : PChar;Check : Char); Integer; far; external 'UseStr'; 

  使用这种方法,程序无法在运行时间里决定DLLs的调用。假如一个特定的DLLs在运行时无法使用,则应用程序将无法执行。 
  2.动态调用或隐式装载 
  使用Windows API函数LoadLibray和GetProcAddress可以实现在运行时间里动态装载DLLs并调用其中的过程。 
  若程序只在其中的一部分调用DLLs的过程,或者程序使用哪个DLLs, 调用其中的哪个过程需要根据程序运行的实际状态来判断,那么使用动态调用就是一个很好的选择。 
  使用动态调用,即使装载一个DLLs失败了,程序仍能继续运行。 

10.2.3 静态调用 

  在静态调用一个DLLs中的过程或函数时,external指示增加到过程或函数的声明语句中。被调用的过程或函数必须采用远调用模式。这可以使用far过程指示或一个{$F +}编译指示。 
  Delphi全部支持传统Windows动态链接库编程中的三种调用方式,它们是: 
  ● 通过过程/函数名 
  ● 通过过程/函数的别名 
  ● 通过过程/函数的顺序号 

  通过过程或函数的别名调用,给用户编程提供了灵活性,而通过顺序号(Index)调用可以提高相应DLL的装载速度。 

10.2.4 动态调用 

10.2.4.1 动态调用中的API函数 

  动态调用中使用的Windows API函数主要有三个,即:Loadlibrary,GetProcAddress和Freelibrary。 
   1.Loadlibrary: 把指定库模块装入内存 
  语法为: 

  function Loadlibrary(LibFileName: PChar): THandle; 

LibFileName指定了要装载DLLs的文件名,如果LibFileName没有包含一个路径,则Windows按下述顺序进行查找: 
  (1)当前目录; 
  (2)Windows目录(包含win.com的目录)。函数GetWindowDirectory返回这一目录的路径; 
  (3)Windows系统目录(包含系统文件如gdi.exe的目录)。函数GetSystemDirectory返回这一目录的路径; 
  (4)包含当前任务可执行文件的目录。利用函数GetModuleFileName可以返回这一目录的路径; 
  (5)列在PATH环境变量中的目录; 
  (6)网络的映象目录列表。 
  如果函数执行成功,则返回装载库模块的实例句柄。否则,返回一个小于HINSTANCE_ERROR的错误代码。错误代码的意义如下表: 

   表10.2 Loadlibrary返回错误代码的意义 
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ 
错误代码         意        义 
-------------------------------------- 
    0 系统内存不够,可执行文件被破坏或调用非法 
    2 文件没有被发现 
    3 路径没有被发现 
    5 企图动态链接一个任务或者有一个共享或网络保护错 
    6 库需要为每个任务建立分离的数据段 
     8 没有足够的内存启动应用程序 
   10 Windows版本不正确 
    11 可执行文件非法。或者不是Windows应用程序,或者在.EXE映 
      像中有错误 
    12 应用程序为一个不同的操作系统设计(如OS/2程序) 
13 应用程序为MS DOS4.0设计 
    14 可执行文件的类型不知道 
    15 试图装载一个实模式应用程序(为早期Windows版本设计) 
16 试图装载包含可写的多个数据段的可执行文件的第二个实例 
    19 试图装载一个压缩的可执行文件。文件必须被解压后才能被装裁 
    20 动态链接库文件非法 
    21 应用程序需要32位扩展 
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ 

  假如在应用程序用Loadlibrary调用某一模块前,其它应用程序已把该模块装入内存,则Loadlibrary并不会装载该模块的另一实例,而是使该模块的"引用计数"加1。 

  2.GetProcAddress:捡取给定模块中函数的地址 
  语法为: 

  function GetProcAddress(Module: THandle; ProcName: PChar): TFarProc; 

Module包含被调用的函数库模块的句柄,这个值由Loadlibrary返回。如果把Module设置为nil,则表示要引用当前模块。 
  ProcName是指向含有函数名的以nil结尾的字符串的指针,或者也可以是函数的次序值。如果ProcName参数是次序值,则如果该次序值的函数在模块中并不存在时,GetProcAddress仍返回一个非nil的值。这将引起混乱。因此大部分情况下用函数名是一种更好的选择。如果用函数名,则 
函数名的拼写必须与动态链接库文件EXPORTS节中的对应拼写相一致。 
  如果GetProcAddress执行成功,则返回模块中函数入口处的地址,否则返回nil。 

3.Freelibrary:从内存中移出库模块 
  语法为: 

  procedure Freelibrary(Module : THandle); 

Module为库模块的句柄。这个值由Loadlibrary返回。 
  由于库模块在内存中只装载一次,因而调用Freelibrary首先使库模块的引用计数减一。如果引用计数减为0,则卸出该模块。 
  每调用一次Loadlibrary就应调用一次FreeLibray,以保证不会有多余的库模块在应用程序结束后仍留在内存中。 

10.2.4.2 动态调用举例 

  对于动态调用,我们举了如下的一个简单例子。系统一共包含两个编辑框。在第一个编辑框中输入一个字符串,而后在第二个编辑框中输入字符。如果该字符包含在第一个编辑框的字符串中,则标签框显示信息:"位于第n位。",否则显示信息:"不包含这个字符。"。如图是程序的运 
行界面。 



图10.1 DLL动态调用实例运行界面 

  输入检查功能的实现在Edit2的OnKeyPress事件处理过程中,程序清单如下。 

procedure TForm1.Edit2KeyPress(Sender: TObject; var Key: Char); 
var 
order: Integer; 
txt: PChar; 
PFunc: TFarProc; 
Moudle: THandle; 
begin 
Moudle := Loadlibrary('c:/dlls/example.dll'); 
if Moudle > 32 then 
begin 
Edit2.text := ''; 
Pfunc := GetProcAddress(Moudle,'Instr'); 
txt := StrAlloc(80); 
txt := StrPCopy(txt,Edit1.text); 
Order := TInstr(PFunc)(txt,Key); 
if Order = -1 then 
Label1.Caption := '不包含这个字符 ' 
else 
Label1.Caption := '位于第'+IntToStr(Order+1)+'位'; 
end; 
Freelibrary(Moudle); 
end; 

  在利用GetProcAddess返回的函数指针时,必须进行强制类型转换: 

Order := TInstr(PFunc)(text,Key); 

  TInStr是一个定义好了的函数类型: 

type 
TInStr = function(Source: PChar;Check: Char): Integer; 

10.3 利用DLLs实现数据传输 

10.3.1 DLLs中的全局内存 

  Windows规定:DLLs并不拥有它打开的任何文件或它分配的任何全局内存块。这些对象由直接或间接调用DLLs的应用程序拥有。这样,当应用程序中止时,它拥有的打开的文件自动关闭,它拥有的全局内存块自动释放。这就意味着保存在DLLs全局变量中的文件和全局内存块变量在DLLs 
没有被通知的情况下就变为非法。这将给其它使用该DLLs的应用程序造成困难。 
  为了避免出现这种情况,文件和全局内存块句柄不应作为DLLs的全局变量,而是作为DLLs中过程或函数的参数传递给DLLs使用。调用DLLs的应用程序应该负责对它们的维护。 
  但在特定情况下,DLLs也可以拥有自己的全局内存块。这些内存块必须用gmem_DDEShare属性进行分配。这样的内存块直到被DLLs显示释放或DLLs退出时都保持有效。 
  由DLLs管理的全局内存块是应用程序间进行数据传输的又一途径,下面我们将专门讨论这一问题。 

10.3.2 利用DLLs实现应用程序间的数据传输 

  利用DLLs实现应用程序间的数据传输的步骤为: 
  1. 编写一个DLLs程序,其中拥有一个用gmem_DDEShare属性分配的全局内存块; 
  2. 服务器程序调用DLLs,向全局内存块写入数据; 
  3. 客户程序调用DLLs,从全局内存块读取数据。 

10.3.2.1 用于实现数据传输的DLLs的编写 

  用于实现数据传输的DLLs与一般DLLs的编写基本相同,其中特别的地方是: 
  1. 定义一个全局变量句柄: 

var 
hMem: THandle; 

  2. 定义一个过程,返回该全局变量的句柄。该过程要包含在exports子句中。如: 

function GetGlobalMem: THandle; export; 
begin 
Result := hMem; 
end; 

  3. 在初始化代码中分配全局内存块: 

程序清单如下: 

begin 
hMem := GlobalAlloc(gmem_MOVEABLE and gmem_DDEShare,num); 
if hMem = 0 then 
MessageDlg('Could not allocate memory',mtWarning,[mbOK],0); 
end. 

  num是一个预定义的常数。 
Windows API函数GlobalAlloc用于从全局内存堆中分配一块内存,并返回该内存块的句柄。该函数包括两个参数,第一个参数用于设置内存块的分配标志。可以使用的分配标志如下表所示。 
表10.3 全局内存块的分配标志 
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ 
标 志 意 义 
--------------------------------- 
gmem_DDEShare 分配可由应用程序共享的内存 
gmem_Discardable 分配可抛弃的内存(只与gmem_Moveable连用) 
gmem_Fixed 分配固定内存 
gmem_Moveable 分配可移动的内存 
gmem_Nocompact 该全局堆中的内存不能被压缩或抛弃 
gmem_Nodiscard 该全局堆中的内存不能被抛弃 
gmem_NOT_Banked 分配不能被分段的内存 
gmem_Notify 通知功能。当该内存被抛弃时调用GlobalNotify函数 
gmem_Zeroinit 将所分配内存块的内容初始化为零 
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ 

  有两个预定义的常用组合是: 

GHND = gmem_Moveable and gmem_Zeroinit 
GPTK = gmem_Fixed and gmem_Zeroinit 

  第二个参数用于设置欲分配的字节数。分配的字节数必须是32的倍数,因而实际分配的字节数可能比所设置的要大。 
  由于用gmem_DDEShare分配的内存在分配内存的模块终止时自动抛弃,因而不必调用GlobalFree显式释放内存。 

10.3.2.2 服务器程序的编写 

  服务器程序必须包含对DLL的调用代码,如: 

function GetGlobalMem: THandle; far; external 'c:/dlls/glbmem'; 

  通过调用该函数,服务器可以获得全局内存块的句柄。 
  在写入数据前,服务器必须锁定全局内存,以避免在写入过程中Windows移动该内存块的位置。 
  函数GlobalLock锁定全局内存并返回指向该内存块的指针: 

pMem := GlobalLock(hMem); 

  对pMem的任何修改都会反映到全局内存块中。 
  对内存块进行操作后,调用GlobalUnLock进行解锁。内存块操作之后尽早解锁,有利于Windows充分利用内存资源。 
  服务器写入数据的实现代码如下。 

var 
hMem: THandle; 
pMem: PChar; 
begin 
hMem := GetGlobalMem; {获得全局内存块的句柄} 
if hMem <> 0 then 
begin 
pMem := GlobalLock(hMem); {加锁全局内存块} 
if pMem <> nil then 
begin 
StrPCopy(pMem,Memo1.text); {向全局内存块写入数据} 
GlobalUnlock(hMem); {解锁全局内存块} 
end 
else 
MessageDlg('Couldnot Lock memory block',mtWarning,[mbOK],0); 
end; 

10.3.2.3 客户程序的编写 

  客户程序几乎是服务器程序的翻版。唯一的区别在于一个是写入数据,一个是下载数据。 
下面是客户从全局内存块下载数据的程序清单。 

var 
hMem: THandle; 
pMem: PChar; 
begin 
hMem := GetGlobalMem; {获得全局内存块的句柄} 
if hMem <> 0 then 
begin 
pMem := GlobalLock(hMem); {加锁全局内存块} 
if pMem <> nil then 
begin 
Memo1.text := StrPas(pMem); {从全局内存块读取数据} 
GlobalUnlock(hMem); {解锁全局内存块} 
end 
else 
MessageDlg('Couldnot Lock memory block',mtWarning,[mbOK],0); 
end; 

  服务器程序和客户程序同时运行后的屏幕显示如下图所示。 


图10.2 利用DLLs实现数据传输的屏幕显示 

10.4 利用DLLs实现窗体重用 

  实现窗体重用是Delphi DLLs功能中一个引人注目的特色。当你创建了一个令自己满意的通用窗体并希望能在不同应用程序中使用,特别是希望能在非Delphi 应用程序中使用时,把窗体做进一个动态链接库中是最适当的。这样即使用其它工具开发的应用程序,如C++、Visual 
Basic等,也都可以去调用它。 
  包含窗体的DLLs有100K左右的部件库(Component Library)开销。可以通过把几个窗体编译成一个DLLs来最小化这笔开销。DLl中的不同窗体可以共享部件库。 

10.4.1 利用DLLs实现窗体重用的一般步骤 

  利用DLLs实现窗体重用的步骤是: 
  1.在集成开发环境(IDE)中,按自己的需要设计一个窗体; 
  2.编写一个用于输出的函数或过程。在该函数或过程中,设计的窗体被实例化; 
  3.重复步骤1、2,直到完成所有重用窗体的设计; 
  4.打开工程文件,进行修改,以适应生成 .dll文件的需要: 
  (1).把保留字program设为library; 
  (2).从uses子句中去掉Forms单元; 
  (3).移去begin,end之间的所有代码; 
  (4).在uses子句下,begin…end块之前,添加保留字exprots。exports 后是输出函数名或过程名。 
  5.编译生成DLLs文件; 
  6.在其它应用程序中调用重用窗体。 
  重用窗体的调用同一般DLLs函数或过程的调用完全一致,不再赘述。读者可参看下面的例子。 

10.4.2 窗体重用实例 

  下面我们通过一个具体的实例来说明窗体重用的设计过程。我们在一个名为passform.dll 的文件中储存了一个口令设置窗口和一个口令检查窗口。而后在一个Delphi 编写的程序和一个VB编写的程序中进行调用。事实证明这种方法是完全可行的。 

10.4.2.1 窗体重用DLLs的设计 

  窗体重用DLLs的设计依照(10.4.1)中介绍的步骤进行。DLLs中的两个窗体 SetPassWordForm和GetPassWordForm分别用于设置和检查口令。它们的设计界面如图所示。 


图10.3 口令设置窗口SetPassWordForm设计界面 


图10.4 口令检查窗口GetPassWordForm设计界面 

  窗体类TSetPassWordForm定义了两个数据成员Verified和PassWord,用于记录口令确认状态和设置的口令。TSetPassWordForm的定义如下: 

type 
TSetPassWordForm = class(TForm) 
Label1: TLabel; 
Edit1: TEdit; 
OKBtn: TBitBtn; 
CancelBtn: TBitBtn; 
procedure FormCreate(Sender: TObject); 
procedure Edit1KeyPress(Sender: TObject; var Key: Char); 
private 
{ Private declarations } 
Verified: Boolean; 
public 
{ Public declarations } 
PassWord: PChar; 
end; 

  窗口生成时,对数据成员和部件状态进行初始化: 

procedure TSetPassWordForm.FormCreate(Sender: TObject); 
begin 
Verified := False; 
PassWord := StrAlloc(40); 
OKBtn.Enabled := False; 
Label1.Caption := 'Please Input PassWord:'; 
end; 

  按钮OKBtn在程序启动时Enabled属性设置为False,直到口令被正确设置后Enabled属性才恢复为True。这样就保证了只有口令被正确设置后,口令设置窗口才能正常关闭。否则只能按Cancel按钮取消。 
  在口令设置代码单元中定义了一个输出函数SetPassWord,用于生成口令设置窗口并返回设置的口令: 

function SetPassWord(PWord: PChar): Boolean; 
var 
SetPassWordForm: TSetPassWordForm; 
begin 
Result := False; 
SetPassWordForm := TSetPassWordForm.Create(Application); 
try 
with SetPasswordForm do 
if ShowModal = mrOK then 
begin 
StrCopy(PWord,StrUpper(Password)); 
Result := True; 
end; 
finally 
SetPasswordForm.Free; 
end; 
end; 

  口令成功设置,把PassWord的值拷贝给PWord输出,并返回True。应该注意的是由于 
PWord本身就是指针类型,指向一个字符串的地址,因而虽然PWord用于输出,但在参数表中仍为传值参数,而不是传址参数。另外调用函数StrCopy,要求PWord在传入前已分配内存,否则会导致一个一般保护错。try...finally用于保护窗口所占用内存资源在任何情况下都能正常释放,读 
者可参看第十二章。 
  在口令设置窗口中,为了确保用户记住了设置的口令,在用户输入并按回车键后,要求用户再次输入进行确认。只有用户重新输入的字符串与原设置口令相同,口令设置窗口才能正常关闭 
。否则将原设置口令清空,要求用户再次输入。以上功能的实现在编辑框的OnKeyPress事件处理过程中。 

procedure TSetPassWordForm.Edit1KeyPress(Sender: TObject; var Key: Char); 
begin 
if Edit1.text = '' then Exit; 
if Key = #13 then 
begin 
if Verified then 
if StrPas(PassWord) = Edit1.text then 
begin 
OKBtn.Enabled := True; 
Edit1.Enabled := False; 
OKBtn.SetFocus; 
end 
else 
begin 
Verified := False; 
MessageDlg('PassWord is InValid.',mtWarning,[mbOK],0); 
Edit1.text := ''; 
PassWord := ''; 
Label1.Caption := 'Please Input PassWord:'; 
end 
else 
begin 
Verified := True; 
StrPCopy(PassWord,Edit1.text); 
Edit1.text := ''; 
Label1.caption := 'Please Verify PassWord:'; 
end; 
Key := #0; 
end; 
end; 

  口令检查窗口的实现相对简单,只定义了一个输出函数GetPassWord,用于生成口令检查窗口并返回口令检查的结果。 

function GetPassword(Password: PChar): Boolean; 
var 
GetPasswordForm: TGetPasswordForm; 
begin 
Result := False; 
GetPasswordForm := TGetPasswordForm.Create(Application); 
try 
with GetPasswordForm do 
if ShowModal = mrOK then 
if UpperCase(Edit1.Text) <> StrPas(StrUpper(Password)) then 
MessageDlg('Invalid Password', mtWarning, [mbOK], 0) 
else 
Result := True; 
finally 
PasswordForm.Free; 
end; 
end; 

  PassWord为输入的参数,不能为空,由调用以上函数的程序负责维护。 
  窗口中用户输入口令时回显在屏幕上的字符由编辑框的PassWordChar属性确定。 
  在DLLs的工程文件中,把两个输出函数写到exports子句中。 

library PassForm; 

uses 
GetPass in 'GETPASS.PAS' {PasswordForm}, 
Setpass in 'SETPASS.PAS' {SetPassWordForm}; 

exports 
GetPassword,SetPassWord; 

begin 
end. 


10.4.2.2 Delphi应用程序调用重用窗体 

  在Delphi应用程序中调用重用窗体,首先必须包含passform.dll的两个输出函数: 

function GetPassword(Password: PChar): Boolean; 
far; external 'c:/dlls/PassForm'; 
function SetPassword(PassWord: PChar): Boolean; 
far; external 'c:/dlls/PassForm'; 

  这位于程序单元的implementation部分。 
  而后在过程中调用相应函数实现口令的设置和检查。程序运行后的界面如图。 



图10.5 Delphi应用程序调用重用窗体运行界面 

  口令设置部分的实现代码为: 

procedure TForm1.SetButtonClick(Sender: TObject); 
begin 
PassWord := StrAlloc(40); 
if SetPassWord(PassWord) = False then 
MessageDlg('PassWord is not set',mtInformation,[mbOK],0); 
end; 

  首先为口令字符串分配内存。当口令设置窗体按Cancel按钮取消时,显示相应的信息。 
  口令检查部分的实现代码为: 

procedure TForm1.TestButtonClick(Sender: TObject); 
begin 
if PassWord = nil then 
begin 
MessageDlg('Set password first', mtInformation, [mbOK], 0); 
SetButton.SetFocus; 
Exit; 
end; 
if GetPassword(PassWord) then 
Label1.Caption := 'You are Wellcome !' 
else 
Label1.Caption := 'Sorry,You are InValid User.'; 
end; 

  根据口令检查的结果,在标签框中显示相应的信息。 

10.4.2.3 VB应用程序调用重用窗体 

  VB是微软公司极力推荐的一个可视化开发工具。它虽然并不支持动态链接库的创建,但可以调用标准的Windows API动态链接库和用其它语言编写的动态链接库。为了验证所生成DLLs的普适性,我们用VB开发了一个简单的程序来调用passform.dll中储存的窗体。 
  VB程序的运行界面如图,和(10.5)的Delphi程序基本一致。 



图10.6 VB应用程序调用重用窗体运行界面 

  下面是VB程序的完整代码,和Delphi程序的对应部分基本一致。 

Option Explicit 
Declare Function GetPassWord Lib "c:/dlls/passform.dll" (ByVal PassWord As String) As Integer 
Declare Function SetPassWord Lib "c:/dlls/passform.dll" (ByVal PassWord As String) As Integer 

Dim PassWord As String * 40 

Sub Check_Click () 
If PassWord = "" Then 
MsgBox ("Enter sample password first") 
SetPass.SetFocus 
Else 
If GetPassWord(PassWord) Then 
StatusLbl.Caption = "You are Welcome!" 
Else 
StatusLbl.Caption = "Sorry,You are Invalid User." 
End If 
End If 
End Sub 

Sub SetPass_Click () 
If SetPassWord(PassWord) = 0 Then 
MsgBox ("PassWord is not Set.") 
End If 
End Sub 

  有关VB编程的一些具体问题,读者可参看有关的VB参考书。 
  
10.4.3 小结 

  本章我们讨论的是动态链接库编程。许多可视化开发工具(如Visual Basic)不支持 DLLs的创建,而Delphi在这里又有上乘的表现。特别是窗体重用机制是Delphi对Windows下DLLs编程的一个重大改进。在一般的DLLs编程中也体现了Delphi快捷、方便的特点。动态链接库是 
Windows下程序组织的一种重要方式,使用动态链接库可以极大地保护用户在不同开发工具、不同时期所做的工作。利用动态链接库,用户可以逐步去构筑自己的程序模块库,为今后的工作积累素材。
阅读全文
0 0

相关文章推荐

img
取 消
img