CSDN博客

img ylmg

Delphi的组件读写机制(二)

发表于2003/5/26 11:36:00  526人阅读

分类: delphi

 

 

Ø        TFiler

       先来看一下TFiler类的定义:

  TFiler = class(TObject)

  private

    FStream: TStream;

    FBuffer: Pointer;

    FBufSize: Integer;

    FBufPos: Integer;

    FBufEnd: Integer;

    FRoot: TComponent;

    FLookupRoot: TComponent;

    FAncestor: TPersistent;

    FIgnoreChildren: Boolean;

  protected

    procedure SetRoot(Value: TComponent); virtual;

  public

    constructor Create(Stream: TStream; BufSize: Integer);

    destructor Destroy; override;

    procedure DefineProperty(const Name: string;

      ReadData: TReaderProc; WriteData: TWriterProc;

      HasData: Boolean); virtual; abstract;

    procedure DefineBinaryProperty(const Name: string;

      ReadData, WriteData: TStreamProc;

      HasData: Boolean); virtual; abstract;

    procedure FlushBuffer; virtual; abstract;

    property Root: TComponent read FRoot write SetRoot;

    property LookupRoot: TComponent read FLookupRoot;

    property Ancestor: TPersistent read FAncestor write FAncestor;

    property IgnoreChildren: Boolean read FIgnoreChildren write FIgnoreChildren;

  end;

       TFiler对象是TReaderTWriter的抽象类,定义了用于组件存储的基本属性和方法。它定义了Root属性,Root指明了所读或写的组件的根对象,它的Create方法将Stream对象作为传入参数以建立与Stream对象的联系, Filer对象的具体读写操作都是由Stream对象完成。因此,只要是Stream对象所能访问的媒介都能由Filer对象存取组件。

       TFiler 对象还提供了两个定义属性的public方法:DefinePropertyDefineBinaryProperty,这两个方法使对象能读写不在组件published部分定义的属性。下面重点介绍一下这两个方法。

       Defineproperty ( )方法用于使标准数据类型持久化,诸如字符串、整数、布尔、字符、浮点和枚举。

       Defineproperty方法中。Name参数用于指定应写入DFM文件的属性的名称,该属性不在类的published部分定义。

       ReadDataWriteData参数指定在存取对象时读和写所需数据的方法。ReadData参数和WriteData参数的类型分别是TReaderProcTWriterProc。这两个类型是这样声明的:

  TReaderProc = procedure(Reader: TReader) of object;

  TWriterProc = procedure(Writer: TWriter) of object;

       HasData参数在运行时决定了属性是否有数据要存储。

       DefineBinaryProperty方法和Defineproperty有很多的相同之处,它用来存储二进制数据,如声音和图象等。

       下面来说明一下这两个方法的用途。

       我们在窗体上放一个非可视化组件如TTimer,重新打开窗体时我们发现TTimer还是在原来的地方,但TTimer没有LeftTop属性啊,那么它的位置信息保存在哪里呢?

       打开该窗体的DFM文件,可以看到有类似如下的几行内容:

  object Timer1: TTimer

    Left = 184

    Top = 149

  end

Delphi的流系统只能保存published数据,但TTimer并没有publishedLeftTop属性,那么这些数据是怎么被保存下来的呢?

TTimerTComponent的派生类,在TComponent类中我们发现有这样的一个函数:

procedure TComponent.DefineProperties(Filer: TFiler);

var

  Ancestor: TComponent;

  Info: Longint;

begin

  Info := 0;

  Ancestor := TComponent(Filer.Ancestor);

  if Ancestor <> nil then Info := Ancestor.FDesignInfo;

  Filer.DefineProperty('Left', ReadLeft, WriteLeft,

    LongRec(FDesignInfo).Lo <> LongRec(Info).Lo);

  Filer.DefineProperty('Top', ReadTop, WriteTop,

    LongRec(FDesignInfo).Hi <> LongRec(Info).Hi);

end;

       TComponentDefineProperties是覆盖了它的祖先类TPersistent的方法,在TPersistent类中该方法为空的虚方法。

       DefineProperties方法中,我们可以看出,有一个Filer对象作为它的参数,当定义属性时,它引用了Ancestor属性,如果该属性非空,对象应当只读写与从Ancestor继承的不同的属性的值。它调用TFilerDefineProperty方法,并定义了ReadLeftWriteLeftReadTopWriteTop方法来读写LeftTop属性。

       因此,凡是从TComponent派生的组件,即使它没有LeftTop属性,在流化到DFM文件中,都会存在这样的两个属性。

 

       在查找资料的过程中,发现很少有资料涉及到组件读写机制的。由于组件的写过程是在设计阶段由DelphiIDE来完成的,因此无法跟踪它的运行过程。所以笔者是通过在程序运行过程中跟踪VCL原代码来了解组件的读机制的,又通过读机制和TWriter来分析组件的写机制。所以下文将按照这一思维过程来讲述组件读写机制,先讲TReader,而后是TWriter

 

0 0

相关博文

我的热门文章

img
取 消
img