CSDN博客

img zc0702

如何在实模式下直接访问4GB内存

发表于2003/2/5 19:37:00  666人阅读

  在DOS下编程因为实模式的限制,最大只能访问1M字节内存空间,就算加上打开A20线后可以访问的65520字节也只有区区1088K而已,而这么少的一点内存中还有大量区域被操作系统、BIOS和TSR等程序占用,真正能给程序员使用的空间少得可怜。好在计算机的发展给广大程序员提供了一些解决这个问题的办法。

  最常见的方法有以下几种:

    1. 精减程序的尺寸,同时尽量避免一次使用太多的内存 (有没有搞错?偶只是初学者,不是算法专家耶)
    2. 使用文件覆盖技术,只在使用指定代码时才将其读入内存,执行后释放
(偶的程序怎么就这么慢呢?硬盘狂转中...)
    3. 用标准的DOS扩展技术如EMS、XMS、DPMI
(哇!功能好强,不过程序改起来好累啊)
    4. 自己写保护模式平台
(谁要这么做了别忘了发一份源程序给我啊)
    5. 转移到其他平台如Windows/UNIX/LINUX
(拜托,我只想在DOS下运行啊)

  程序压缩效果再好也是有限,总不能达到50%以上吧,程序要用2M乃至10M内存呢?文件覆盖需要自己编写调度模 块,而且因为频繁读写硬盘,将导致程序运行速度变得很低;EMS、XMS、DPMI功能强大,兼容性强,尤其是DPMI规范不 但支持大内存访问,而且还可以在保护模式下运行代码并能超越64KB的段地址限制,实在是写大型程序时的首选。但EMS 、XMS只能将扩展内存当作高速硬盘使用,所有的访问都只能通过一系列中断调用来完成,对于经常需要小尺寸大批量内 存访问的程序就不太适合,而且使用它们均受制于实模式的64KB段地址空间,对于大数据量访问也不太方便;用DPMI当 然就没有这些限制,但它需要将所有的程序按保护模式的结构改写,这也是一件麻烦的事。自己写保护模式平台(汗!... 这个我想没有几个人做得到吧,我就算做得到也不会做的)。至于转移到其他平台那就不用我说了。

  看到这里,读者不禁会问:“那照这么说来没有一种方法是好的了?” 其实也不是这样,每种方法都有它的优点和缺点,要看你的需要来决定到底使用哪种方法。

  好了,废话说了这么多,再不切入正题的话估计会有人向我扔鸡蛋了,下面就来告诉大家怎么做到在实模式下访问4GB内存。这种技术需要保护模式支持,所以只能在80386以上的CPU中运行。

  学过一点保护模式的读者都知道,在保护模式下段地址寄存器中内容的不再象实模式那样是段的基地址,而只是描述符表中的一个索引,段的真正信息(基地址、限长、访问权限等)放在描述符表中, 当访问一数据时CPU会从描述符表取出段的描述信息来检查访问是否合法,不合法就产生异常,合法则允许访问。每次访问都要读出描述符信息再检查是一个比较费时的过程,为了提高内存访问的速度,Intel公司在CPU中为每个段寄存 器配备了一个高速缓冲器来存放段的描述符信息,这样访问内存时就不用频繁地访问描述表,只要从高速缓冲进行校验就行,只有在改变段寄存器的值时才访问描述符表将新的段描述符装入高速缓冲中。

  我们就利用CPU的这个特性来达成我们的目的。首先进入保护模式,把某个段寄存器设为基地址0H,限长4GB,然后再退回实模式。这样就可以通过该段寄存器直接访问4GB的内存了(实际上只能访 问你的机器上所有的内存而并不是4GB)!还有一点要注意的是一定要打开A20线,否则......别怪我言之不预!

  下面列出所需要的代码:

Make4GBSegment    MACRO    _seg
local   MyGdt,PM_Service,Old_GDTR,GDTR,Real_Service,MyGdt
local   _Exit
    Push    DS
    Push    ES
    Pushad
    Pushfd                            ;保护现场
    
    Sub     EBX,EBX
    Mov     BX,CS
    Mov     DS,BX

    Shl     EBX,4
    Push    EBX

    Rol     EBX,8
    Mov     BYTE Ptr MyGdt[8+7],BL
    Mov     BL,BYTE Ptr MyGdt[8+5]
    Ror     EBX,8
    Mov     DWORD Ptr MyGdt[8+2],EBX

    Pop     EBX
    lea     EBX,[EBX+MyGdt]
    Mov     DWORD Ptr [GDTR+2],EBX
    Mov     WORD Ptr [GDTR],31        ;建立新的GDTR
    Cli

    Sgdt    FWORD Ptr [Old_GDTR]      ;保存旧的GDTR
    Lgdt    FWORD Ptr [GDTR]          ;设置新的GDTR
    Mov     EBX,CR0
    Or      BL,1
    Mov     CR0,EBX                   ;进入保护模式
    DB      0eah
    DW      PM_Service
    DW      8                         ;跳转到保护模式代码执行

PM_Service:
    Mov     AX,16
    Mov     _seg,AX
    Mov     EBX,CR0
    And     EBX,0fffffffeh
    Mov     CR0,EBX
    DB      0eah
    DW      Real_Service
    DW      seg Real_Service

Real_Service:
    Lgdt    FWORD Ptr [Old_GDTR]

    Popfd                             ;恢复现场
    Popad
    Pop     ES
    Pop     DS
    Jmp     _Exit

MyGdt       DQ    0
            DW    -1,0,9a00h,0
            DW    -1,0,9200h,0cfh
            DQ    0

Old_GDTR    DW    0,0,0
GDTR        DW    0,0,0
_Exit:
    Endm

  在这里为了方便我只把FS改成4GB段,读者可以按需要自行决定使用哪个段寄存器。只要将这段代码拷贝到你的程序中,然后在开始的时候调用它,就可以通过该段寄存器直接访问大内存了,爽吧!

  最后还有一点一定要注意:如果你的程序运行时有任何扩展内存管理程序存在(HIMEM、EMM386等)都要千万小心,因为很容易会破坏到它们的内部数据或其他程序的数据,如果是这样就只有死机一条路可走了。切记切记!我的建议是最好从内存顶端开始使用扩展内存。这时破坏其他数据的可能要小一些。

0 0

相关博文

我的热门文章

img
取 消
img